Scripting sur Mac

Finder vs System Events vs UNIX

2011-12-03T18:23:00.000-08:00

tell application "Finder"

set List1 to the name of every item of startup disk

end tell

tell application "System Events"

set List2 to the name of every item of startup disk

end tell

set List3 to do shell script "ls -a /"

(count of List1) = (count of List2)

--> false

(count of List2) = (count of List3)

--> false

>> Ouvrir le script dans l'éditeur

The Zen of Python

2011-11-06T04:57:00.000-08:00

set cmd to do shell script "python -c 'import this'"

display dialog cmd buttons {"•"} default button 1

>> Ouvrir le script dans l'éditeur

Script To Markup Code

2011-10-28T18:14:00.000-07:00

Crée le code des liens de ce blog qui permettent d'ouvrir le script sur le Mac de l'utilisateur.

-- ASCII character (34) -- %22 -- quote

-- ASCII character (32) -- %20 -- espace

-- ASCII character (9) -- %09 -- tabulation

-- ASCII character (10) -- %0A -- retour chariot

-- ASCII character (58) -- %3A -- colon

-- ASCII character (60) -- "%3C" -- <

-- ASCII character (62) -- %3E -- >

set charList to {ASCII character (32), ASCII character (34), ASCII character (9), ASCII character (58), ASCII character (62), ASCII character (60)}

set temp to the clipboard as text

set newText to ""

-- Codage des quote, espace, tabulation, colon, < et >

repeat with theChar in temp

if theChar is in charList then

set newText to newText & encodeChar(theChar)

else

set newText to newText & theChar

end if

end repeat

-- Codage des retour chariot

set theParagraphs to every paragraph of newText

set newContents to ""

repeat with thisParagraph in theParagraphs

set thisParagraph to thisParagraph & "%0A" as string

set newContents to newContents & thisParagraph as string

end repeat

-- Ecriture du lien HTML cliquable dans le presse-papiers

set the clipboard to " & (ASCII character (34)) & "applescript://com.apple.scripteditor?action=new&script=" & newContents & (ASCII character (34)) & ">>> Ouvrir le script dans l'éditeur"

on encodeChar(this_char)

set the ASCII_num to (the ASCII number this_char)

set the hex_list to {"0", "1", "2", "3", "4", "5", "6", "7", "8", "9", "A", "B", "C", "D", "E", "F"}

set x to item ((ASCII_num div 16) + 1) of the hex_list

set y to item ((ASCII_num mod 16) + 1) of the hex_list

return ("%" & x & y) as string

end encodeChar

iTunes Tag Concatenate

2011-10-28T17:51:00.000-07:00

property separator : "+" -- Séparateur des Tags concaténés

tell application "iTunes"

activate

set theseTracks to selection of browser window 1 -- Liste des pistes selectionnées

end tell

-- Vérification sélection non vide

if theseTracks is {} then

beep

display dialog "Sélectionnez les pistes à modifier." buttons {"Annuler"} default button 1 with icon 0

return

end if

-- Sélection des Tags à concatener

set theChoice to choose from list {¬

"1 | TITRE + ARTISTE | | Artiste de l'album | Album ", ¬

"2 | | TITRE + ARTISTE | Artiste de l'album | Album ", ¬

"3 | Titre | ARTISTE + ARTISTE DE L'ALBUM | | Album", ¬

"4 | Titre | | ARTISTE + ARTISTE DE L'ALBUM | Album", ¬

"5 | Titre | Artiste | ARTISTE dE L'ALBUM + ALBUM ||", ¬

"6 | Titre | Artiste | | ARTISTE dE L'ALBUM + ALBUM", ¬

"7 | TITRE + ARTISTE DE L'ALBUM | Artiste | | Album", ¬

"8 | | Artiste | TITRE + ARTISTE DE L'ALBUM | Album", ¬

"12 | Titre | | Artiste de l'album | ARTISTE + ALBUM |"} with prompt "Sélectionner les Tags à concaténer :" & return & " | Titre | Artiste | Artiste de l'album | Album |"

if theChoice is false then error "Annulation Utilisateur" number -128

-- numéro de la ligne selectionnée dans la liste

set num to (first word of (theChoice as string)) as number

-- choix du séparateur de Tags

set separator to text returned of (display dialog "Choisisez un séparateur de Tags" default answer separator)

-- concaténation des Tags sélectionnés

tell application "iTunes"

set ofi to fixed indexing

set fixed indexing to true

with timeout of 9999 seconds

repeat with theTrack in theseTracks

if num = 1 then

tell theTrack to set name to (get name) & separator & (get artist)

tell theTrack to set artist to ""

else if num = 2 then

tell theTrack to set artist to (get name) & separator & (get artist)

tell theTrack to set name to ""

else if num = 3 then

tell theTrack to set artist to (get artist) & separator & (get album artist)

tell theTrack to set album artist to ""

else if num = 4 then

tell theTrack to set album artist to (get artist) & separator & (get album artist)

tell theTrack to set artist to ""

else if num = 5 then

tell theTrack to set album artist to (get album artist) & separator & (get album)

tell theTrack to set album to ""

else if num = 6 then

tell theTrack to set album to (get album artist) & separator & (get album)

tell theTrack to set album artist to ""

else if num = 7 then

tell theTrack to set name to (get name) & separator & (get album artist)

tell theTrack to set album artist to ""

else if num = 8 then

tell theTrack to set album artist to (get name) & separator & (get album artist)

tell theTrack to set name to ""

else if num = 9 then

tell theTrack to set name to (get name) & separator & (get album)

tell theTrack to set album to ""

else if num = 10 then

tell theTrack to set album to (get name) & separator & (get album)

tell theTrack to set name to ""

else if num = 11 then

tell theTrack to set artist to (get artist) & separator & (get album)

tell theTrack to set album to ""

else if num = 12 then

tell theTrack to set album to (get artist) & separator & (get album)

tell theTrack to set artist to ""

end if

end repeat

end timeout

set fixed indexing to ofi

end tell

display dialog "Opération terminée." buttons {"OK"} default button 1 with icon note giving up after 5

>> Ouvrir le script dans l'éditeur

Histoire d'Héritage

2011-06-02T17:00:00.000-07:00

script pomme

property couleur : "ROUGE"

on afficherCouleur()

display alert "Script pomme" message "Cette pomme est " & couleur buttons {"OK"} default button 1

display alert "Script pomme" message "Cette pomme est " & couleur of me buttons {"OK"} default button 1

end afficherCouleur

end script

script banane

property parent : pomme

property couleur : "JAUNE"

on afficherCouleur()

display alert "Script banane" message "Cette banane est " & couleur buttons {"OK"} default button 1

continue afficherCouleur()

end afficherCouleur

end script

script poire

property parent : banane

property couleur : "VERTE"

end script

tell pomme to afficherCouleur()

-- affiche sa propriété : "Cette pomme est ROUGE"

tell banane to afficherCouleur()

-- affiche sa propriété : "Cette banane est JAUNE"

-- puis transmet au parent qui affiche sa propriété : "Cette pomme est ROUGE"

-- et affiche la propriété du fils : "Cette pomme est JAUNE"

tell poire to afficherCouleur()

-- transmet au parent qui affiche sa propriété : "Cette banane est JAUNE"

-- qui transmet au grand-parent qui affiche sa propriété : "Cette pomme est ROUGE"

-- et affiche la propriété du petit-fils : "Cette pomme est VERTE"

>> Ouvrir le script dans l'éditeur

Fondations

2011-05-30T02:20:00.000-07:00

>> The Development of AppleScript by William R. Cook

AppleScript et Revolution

2011-05-02T16:09:00.000-07:00

Pour executer du code AppleScript dans une pile Revolution, utiliser la commande "do as applescript".

on mouseUp

do ("choose folder") as applescript

end mouseUp

Si la commande est complexe la stocker dans un champ caché ou dans une custom property (dans les exemples suivants le code Applescript est stocké dans la custom property du bouton) puis l'exécuter comme précédemment.

on mouseUp

put myCustomProperty of me into AScode

-- ou en utilisant un champ caché :

-- put field "myField" into AScode

do AScode as applescript

end mouseUp

Si la commande contient des paramètres utiliser la commande "replace with in"

display dialog "##param##"

on mouseUp

put myCustomProperty of me into AScode

replace "##param##" with "Hello World" in AScode

do AScode as applescript

end mouseUp

>> A journey through Revolution : Using AppleScript from within Revolution

Homesickness

2011-05-02T15:18:00.001-07:00

"I still believe that HyperCard is the best program ever written"
Steve Wozniak (Juin 2001)

Automator Action

2010-05-07T08:03:00.000-07:00

>> Write Your Own Automator Actions by Matt Neuburg

Oldies

2010-01-16T19:14:00.000-08:00

Quelques routines vanilla écrites il y a une dizaine d'années.
Une routine vanilla utilise le vocabulaire standard d'un langage de script sans ajout externe. L'expression viendrait des USA où les glaces sont parfumées à la vanille par défaut. Les scripts présentés ne sont pas nécessairement compliqués mais sont les premières pièces d'un jeu de construction en réponse au message de Bill Atkinson, le créateur d'HyperCard : “ Scripts are like haïkus. ”
>> Lire la suite...

Plug-in Manager

2009-11-08T04:02:00.000-08:00

tell SwitchFile to getProperties()

if the result is {"", ""} then tell SwitchFile to setProperties(choose folder with prompt "activated items :", choose folder with prompt "Inactivated items :")

tell SwitchFile to process()

script SwitchFile

property folderA : "" -- chemin d'accès au dossier contenant les items activés

property folderB : "" -- chemin d'accès au dossier contenant les items inactivés

property theMark : "√"

-- retourne le chemin d'accès des dossiers items activés/desactivés

on getProperties()

return {folderA, folderB}

end getProperties

-- enregistre le chemin d'accès des dossiers items activés/desactivés

on setProperties(a, b)

set folderA to a

set folderB to b

end setProperties

-- Boite de dialogue d'activation/desactivation des items

on process()

tell application "Finder"

set fileNameA to my addgizmo2List(theMark, the name of every file of folder folderA)

set fileNameB to the name of every file of folder folderB

set filesToMove to (choose from list (fileNameA & fileNameB) with prompt "Select items to switch :" with multiple selections allowed)

if filesToMove is not false then

repeat with fileName in filesToMove

if fileName starts with theMark then

set fileName to my deletegizmo(theMark, fileName) as string

my moveitem(folderA, folderB, fileName)

else

my moveitem(folderB, folderA, fileName)

end if

end repeat

end if

end tell

end process

-- deplacement d'un item d'un dossier vers un autre

on moveitem(folderA, folderB, fileName)

tell application "Finder"

move (every file of folderA whose name is fileName) to folderB

end tell

end moveitem

-- coche l'item qui se trouve dans le dossier des items activés

on addgizmo2List(gizmo, theList)

set temp to {}

repeat with theItem in theList

copy ((gizmo & theItem) as string) to the end of temp

end repeat

return temp

end addgizmo2List

-- décoche l'item désactivé qui se trouve dans le dossier des items inactivés

on deletegizmo(gizmo, theText)

if theText starts with gizmo then return (characters 2 thru -1 of theText) as string

return theText

end deletegizmo

end script

Ce gestionnaire rudimentaire de plug-in illustre la réflexion de Gwénaël à propos des objets scripts >>ici

>>Ouvrir le script dans l'éditeur

AppleScript 1 - UNIX 0

2009-05-03T10:19:00.000-07:00

Compte le nombre d'occurences d'un caractère à l'intérieur d'un texte.

AScountChar("hébété", "é")

UNIXcountChar("hébété", "é")

-- Retourne le nombre d'occurence d'un caractère d'un texte.

on AScountChar(theString, charToSearch)

set text item delimiters of AppleScript to charToSearch

set la_liste to text items of theString

set text item delimiters of AppleScript to ""

return (count la_liste) - 1

end AScountChar

Auteur : Fred;o

-- la même chose en Shell UNIX

on UNIXcountChar(theString, chartoFind)

return (do shell script "echo" & quote & theString & quote & " | tr -cd " & quote & chartoFind & quote & " | wc -c") as number

end UNIXcountChar

>>Ouvrir le script dans l'éditeur

HyperCard memories

2009-05-02T17:25:00.000-07:00

"Il est assez remarquable de constater qu'Hypercard est souvent apprécié comme bonne introduction à la programmation. Personnellement, je le pratique depuis quinze ans...sans jamais penser programmation mais seulement scripting. Un bon programmeur, selon l'air du temps, fait du C, du Pascal ou autre... Scripter HyperCard c'est une affaire de novice... Ce n'est pas discutable, c'est ainsi... J'ai perdu beaucoup de temps à essayer d'expliquer autour de moi que ce n'était là que préjugés, qu'il fallait y regarder de plus près techniquement... grossière erreur de ma part. Il n'y a rien de technique là-dedans... Que l'utilisateur utilise et que le programmeur programme... Chacun à sa place, et les vaches seront bien gardées...voilà bien le non-dit. Et dans ce contexte, passer d'HyperCard au C autorise un changement de statut social (souvent fantasmé) que l'on préfère mettre au compte d'une modification de savoir.

C'est du coté de Bourdieu qu'il faut plutot chercher la compréhension de ces discussions de sourds, et considérer que l'informatique n'est pas soumise aux idéologies est assez naif (d'autant plus qu'ici, dans cet isolat numérique, il n'est pas seulement question de discours sur une pratique mais de pratique comme élément de discours, ce qui peut se révéler assez pervers, puisque l'on peut mettre ces éléments de discours au compte des faits sur lesquels on discute).

(...) Je dis qu'il est notoirement accepté que l'on ne fait rien de vraiment bon avec Hypercard...et pense que cette appréciation d'ordre technique cache en fait un verrouillage social...en gros que c'est du bourrage de crane. Il semble accepté que la différence entre outil de scripting et outil de programmation soit une différence technique...langage interprété, langage compilé, etc... cela me semble la partie résiduelle du problème... du moins pour ce qui concerne Hypercard.

Dans l'esprit de Bill Atkinson, la pratique de la programmation, sous la forme du scripting, devait être étendue à une population considérée jusqu'alors comme uniquement utilisatrice de logiciels. C'est-à-dire qu'un instituteur, un médecin, un bibliothécaire, un comptable pouvait s'approprier cette technique pour être, comme le disait si bien récemment Steve Wozniak, maître et non esclave de son ordinateur.

Chaque métier a ses particularités, et pour ne prendre qu'un seul exemple, le bibliothécaire, celui-ci ne travaille pas du tout de la même manière selon qu'il exerce dans une faculté ou un comité d'entreprise d'usine. Or comme l'outil informatique est son principal outil de travail, celui-ci se trouve enfermé, embrigadé, dans des procédures informatiques qui méconnaissent ses particularités de travail, s'il est entièrement soumis à l'outillage des logiciels standards. Cela peut geler ou assécher même ses capacités d'innovations dans son travail. Hypercard reconnaissait que son métier de base était d'être bibliothécaire et non informaticien, et lui fournissait juste ce qu'il fallait pour enrichir son travail en procédures informatiques... sans qu'il soit contraint de négliger son travail de base (s'il se met à Java...il aura tendance à ne plus en foutre une rame en matière de bibliothèque, l'ubiquité n'étant pas donnée à tout le monde...:-)). Ce "juste ce qu'il fallait" a été interprété, de manière interessée, comme une défaillance technique du produit par ceux qui entendent faire qu'un consommateur reste un consommateur.

En matière d'efficacité globale, hypercard remplissait son contrat...parce que ce qui compte, c'est ce que cela donne ... à la finale. Une comparaison entre logiciels reste incomplète si l'on n'inclut pas ce que cela donne in situ (ce qui signifie ici l'enrichissement par l'utilisateur d'hypercard du logiciel de base).

Je ne parle pas de scripting en général, mais bien d'hypercard, en particulier. Je ne dirais pas cela pour Frontier (ou Radio) par exemple...pour AppleScript, par contre le sujet est posé ;-) En d'autre terme, je ne parlais pas technique. Je disais qu'hypercard traçait le dessin d'un certain type de relation sociale potentielle autour de l'activité informatique. Son abandon correspond à une régression, de ce point de vue. Avec des effets techniques induits, évidemment (une communauté de scripteurs qui s'évapore), et là, Apple a loupé le coche."

Gwénaël Le Dréan le 01/09/2002 sur Palimpseste

Cut Tag

2008-09-30T16:13:00.000-07:00

Supprime les chaînes de caractères comprises entre un couple de balises différentes, balises incluses.
Exemple : {texte a effacer} texte a garder {texte a effacer} texte a garder
tag1 : {
tag2 : }
>>Download action 16Ko

Read File

2008-09-24T16:05:00.001-07:00

>>Download Action 12Ko

Find Replace

2008-09-24T00:36:00.000-07:00

>>Download Action 16Ko

Levenshtein distance

2008-07-24T09:49:00.000-07:00

Par Gary de la liste applescript-users@lists.apple.com

La distance de Levenshtein est égale au nombre minimal de caractères qu'il faut supprimer, insérer, ou remplacer pour passer d’une chaîne à l’autre.

on LEVENSHTEIN_DISTANCE(thisText, thatText)

set phpScr to "$lev=levenshtein('" & thisText & "', '" & thatText & "');echo $lev;"

set shCmdStub to "php -r "

set sh to shCmdStub & (quoted form of phpScr)

set res to do shell script sh

end LEVENSHTEIN_DISTANCE

LEVENSHTEIN_DISTANCE("the", "they") --> 1

LEVENSHTEIN_DISTANCE("hello world", "hell worm") --> 3

>>Ouvrir le script dans l'éditeur

En savoir plus ...

Les objets 2/2

2008-07-12T15:03:00.000-07:00

"La documentation officielle est claire et traite des variables globales, locales et des propriétés comme des variantes de variables. Du point de vue de la technique, rien à redire... Mais essayons un peu de nous extraire un moment de l'écriture informatique et de nous demander ce que pouvait bien avoir dans la tête l'équipe de developpement d'AppleScript (spéculons légèrement, à défaut de pouvoir le faire sauvagement).

Il est possible que la confrontation avec Hypercard que je vais faire soit historiquement erronée, mais l'hypothèse semble toutefois fonctionner (même à tort :-)). Le rêve de Bill Atkinson était que les Hypercardiens échangent leurs piles, à savoir des fragments de connaissance; d'un point de vue informatique, un échange de données. L'échange de fonctionnalités se trouvant au fond du panier, d'un point de vue technique, était secondaire, hors les fonctions externes (justement). Donc, chacun écrit ses routines en Hypertalk et les agglutine à la queu leu-leu dans les scripts. Comment ces routines entretiennent-elles des relations les unes avec les autres ? On n'en sait que couic, hors l'auteur (et encore, pendant quelques jours... après il s'exerce, lui aussi, à l'herméneutique). Les fonctions externes possèdent par contre cette qualité de pouvoir être échangées, comme fonctionnalités, et possèdent une description des points d'entrée et de sortie qui les rendent utilisables dans des contexte variés. Mais elles ne sont pas au coeur du système.

C'est la différence avec AppleScript. Il est possible qu'historiquement les premiers AppleScripteurs furent les HyperCardiens. Force de l'inertie, la coutume perdura, qui fit construire les scripts AS autour des routines (les handlers). Puisque cela fonctionne bien ainsi, pourquoi aller voir plus loin. Je ne crois pas que cela corresponde pourtant au rêve de l'équipe de developpement d'AppleScript (rêve spéculé, je le répète), puisque l'objet script (nourri de propriétés, qui se distinguent sous cet angle des autres variables) offre un supplément de puissance étonnant à AppleScript, permettant l'échange de fragments de fonctionnalités informatique de manière très propre.

L'échange n'est pas un élément de syntaxe, et la documentation n'a pas vocation de donner dans les humanités, mais le pourquoi des dispositifs fournis est peut-être quand même à rechercher chez des auteurs en chair et en os. Certes, l'objet script apporte une plus grande lisibilité des pages de scripts, le travail est mieux structuré, mais ce n'est pas là, à mes yeux, le plus important. Cela suppose surtout une modification de comportement, hors la technique immédiate. Nous n'avons plus seulement un scripteur qui écrit face à un utilisateur potentiel, mais un jeu à trois personnes mettant en scène le scripteur, l'utilisateur et un autre scripteur virtuel, dont le premier tient compte dans son écriture de script même (mais comme il est virtuel, on n'en tient évidemment pas compte actuellement, c'est le problème). Une modification d'approche, plus qu'un complément de savoir.

Je m'explique: mettons que quelqu'un écrive un gestionnaire de plug-in pour Photoshop. Il va créer une interface permettant
d'activer ou de désactiver des éléments d'une liste affichée représentant ces plug-in dont la classe de base sera "fichier", l'activation et la désactivation consistant à déplacer des fichiers du finder d'un dossier à un autre. L'interface prête au générique, puisque c'est un cas de figure fréquent, et la manipulation de fichiers tout autant, des scripts enfants pouvant varier selon la nature des fichiers manipulés (avec les incidences sur les menus)... Un vrai magasin de fonctions ou tout le monde peut se servir (pas par copier/coller... mais par "tell script bidule" ce qui rend dynamique tout le système...) pour peu que tout soit assez bien segmenté et rendu autonome. Cela signifie ensuite une diffusion publique et sélective de certaines déclarations de scripts, de certaines propriétés qu'ils contiennent (puisque l'on peut accéder à un état des propriétés de script sans exécution de commande particulière autre que "get") et de diverses commandes susceptibles d'être publiques. C'est-à-dire rendre publique tous les points d'entrées et de sorties autorisés sous une forme que l'on pourrait nommer... dictionnaire...on les aime chez les autres (les applications) mais les récusons chez nous, pratiquants du script,...c'est quand même bizarre.

Bref, ce travail fait avec des objets scripts autorise ensuite un petit malin qui aurait l'intention de faire un gestionnaire de
compléments de pilotage de s'épargner beaucoup de travail[...]Sans les propriétés, cette manière de voir les choses ne serait pas possible."

Gwénaël Le Dréan le 12/11/2001 sur la liste AppleScript francophone

Les objets 1/2

2008-07-12T14:56:00.000-07:00

"Le script principal, celui que l'on écrit de prime abord sur une feuille vierge, est un objet de type script, à l'égal de tout autre.
La seul différence qui le différencie d'un autre est que sa déclaration (script premier ... end script) est implicite, tout comme sa commande run d'exécution. Cette omission est justifiée (mais pourrait aussi justifier sa désignation sous un nom particulier, comme superscript) par le bon sens... mais les effets induits par cette omission ont finalement éroder le sens même. Ainsi, il n'est plus fait de différence, dans la pratique courante, entre un script et ce qu'il serait préférable de nommer feuille de script, feuillet de script, formulaire de script, ou autre nom pour désigner le support physique du script et le distinguer de ce qu'il contient.

Le symptome principal de cette dérive est que l'on a l'habitude de se donner les uns les autres des superscripts (le script principal, donc) et/ou/avec des routines (ou méthodes, bref les handlers). Si le secret bien gardé d'Apple est AppleScript, le secret bien gardé d'AppleScript est l'objet de type script.

La première caractéristique d'un objet script est d'être un objet. Partant de là, la notion de Propriété n'est pas essentiellement
(quoique je reconnaisse que la documentation officielle prête légèrement (par l'emploi du mot variable, qui n'est pourtant pas faux, d'un point de vue technique) à confusion) la différence de pérennité de son état par rapport aux variables globales et locales. Cette pérennité est liée en fait, nécessairement, à la définition du mot Objet. La Propriété n'est pas essentiellement une facilité, comme outillage de programmation de mémorisation de valeurs comme les variables locales et globales, mais bien une nécessité existentielle pour un objet. Un objet "pomme", dont la propriété couleur possèderait une valeur "rouge" et la propriété grosseur possèderait une valeur "petite" qui disparaitraient toutes deux après l'exécution d'un script, perdrait, pour autant que le nombre de propriétés le caractérisant soit relativement complet, sa caractéristique d'objet reconnaissable en tant que pomme, parmi tous autres objets. La propriété ne dépend donc pas de l'exécution d'un script.

La nature de la Propriété, n'est pas inclue, à mon sens, dans une interrogation du "qu'est-ce que cela fait", mais du "qu'est-ce que cela est". C'est-à-dire que je tente, en scriptant, de décrire un espace encombré d'objets (potentiels ou réels) et non d'actions (on comprend, du coup, pourquoi une propriété est accessible de l'"extérieur"; ce qui compte est que l'objet existe).

Les actions porteront, entre autre, sur cet espace et ces objets reconnus, en modifiant notamment les valeurs des propriétés
des objets. La date de dernière sauvegarde est l'une des propriétés de l'objet backup, ainsi même que l'on peut se définir en français les propriétés nécessaires pour caractériser ce mot backup (ce qui pose vraiment la question de la définition d'un objet, en général, puisque je prend volontairement comme exemple ce qui n'est associé, en principe, qu'à une suite d'actions :)).

Je semble peut-être couper les cheveux en quatre, mais je ne le crois pas,parceque l'échange d'objets seraient autrement plus bénéfiques que l'échange de routines. Or, si nous examinons généralement attentivement le dispositif des objets que l'on manipule par script dans les applications scriptables, il est moins fréquent d'être aussi bien disposé avec les objets que l'on pourrait manipuler dans le script même, pour peu qu'on définisse justement comme objets au préalable ce que l'on triture empiriquement.

L'une des grosses critiques faite à Hypercard, qui se présentait comme application objet, était qu'il était bridé, que l'on ne pouvait pas créer (inventer) d'objets. Cette contrainte est levée avec AppleScript, en grande partie grace aux Propriétés."

Gwénaël Le Dréan le 10/11/2001 sur la liste AppleScript francophone

Bricolage et conception

2008-07-12T02:50:00.000-07:00

"Le bricolage, consiste à partir d'une collection finie d'outils et de matériaux, à chercher comment les agencer pour réaliser quelque chose. L'idée émerge donc peu à peu des essais et de la réalisation. Le bricolage consiste à faire avec ce qu'on a sous la main, et le bricoleur collectionne volontiers des trucs et des machins qui "pourront toujours servir".
La conception consiste, au contraire, à partir d'une idée, à en faire un modèle ou un plan sans tenir compte de la disponibilité immédiate des matériaux et des outils. Le concepteur définit ses besoins puis se met en quête de ce qu'il lui faut. Il peut naturellement être amené dans la logique de sa démarche, à créer ou faire créer des outils ou des matériaux qui n'existent pas."

Laurent Sebilleau d'après Claude Levi-Strauss

Archive and Backup ExpressVitale

2008-07-08T14:58:00.001-07:00

>>Télécharger l'action "Type Keystroke"

DataBase (5/5)

2008-07-06T04:12:00.001-07:00

on read_file(thePath)

try

set thePath to thePath as string

set idFile to open for access file thePath

set fileData to read idFile as list

close access idFile

on error errMsg number errNum

close access file thePath

return false

end try

return fileData

end read_file

on write_file(theText, thePath)

try

set thePath to thePath as string

set idFile to open for access file thePath with write permission

write theText to idFile starting at 0 as list

close access id_file

return true

on error

close access file thePath

return false

end try

end write_file

-- Check the entry in a dialog box who must not be empty

on checkEmptyDialog(theText, defaultAnswer)

repeat

set theAnswer to text returned of (display dialog theText default answer defaultAnswer with icon 1)

if (count theAnswer) > 0 then exit repeat

end repeat

return theAnswer

end checkEmptyDialog

-- Return the number of one item in a list

on ItemNumber(theItem, theList)

repeat with NumItem from 1 to count theList

if theItem = item NumItem of theList then return NumItem

end repeat

return 0

end ItemNumber

on ASTID(x) -- set item delimiter to x

set AppleScript's text item delimiters to x

end ASTID

>>Ouvrir le script dans l'éditeur

DataBase (4/5)

2008-07-06T04:11:00.000-07:00

on createCard(a, b, c, d, e)

script

property item1 : a -- Auteur

property item2 : b -- Titre

property item3 : c -- Sujet

property item4 : d -- Edition

property item5 : e -- critere tri

on getInfos()

if item5 is "Auteur" then

return item1 & " • " & item2 & " • " & item3 & " • " & item4

else if item5 is "Titre" then

return item2 & " • " & item1 & " • " & item3 & " • " & item4

else if item5 is "Sujet" then

return item3 & " • " & item1 & " • " & item2 & " • " & item4

else

return item4 & " • " & item1 & " • " & item2 & " • " & item3

end if

end getInfos

on getInfos2()

if item5 is "Auteur" then

return item1

else if item5 is "Titre" then

return item2

else if item5 is "Sujet" then

return item3

else

return item4

end if

end getInfos2

end script

end createCard

>>Ouvrir le script dans l'éditeur

DataBase (3/5)

2008-07-06T04:10:00.000-07:00

on newCard()

set item1 to text returned of (display dialog "Auteur :" default answer "" with icon 1)

set item2 to text returned of (display dialog "Titre :" default answer "" with icon 1)

set item3 to text returned of (display dialog "Sujet :" default answer "" with icon 1)

set item4 to text returned of (display dialog "Edition :" default answer "" with icon 1)

set item5 to "Auteur" -- tri par defaut

set the end of allCards to createCard(item1, item2, item3, item4, item5)

end newCard

>>Ouvrir le script dans l'éditeur

DataBase (2/5)

2008-07-06T04:09:00.000-07:00

on CardList()

if allCards = {} then

display dialog "DataBase empty." with icon 0

return {}

end if

set btn to button returned of (display dialog "DataBase" buttons {"Search...", "Show cards"} default button 2 with icon 1)

set SortBy to choose from list {"Auteur", "Titre", "Sujet", "Edition"} with prompt "Sort by :" cancel button name "Retour"

if SortBy is false then return

set SortBy to item 1 of SortBy

set listeInfos to {}

if btn is "Show cards" then

-- afficher les cartes

repeat with theCard in allCards

set (item5 of theCard) to SortBy

copy (getInfos() of theCard) to the end of listeInfos

end repeat

set cardToDelete to (choose from list listeInfos with prompt "DataBase" OK button name "Delete" cancel button name "Back")

-- effacer une carte

if cardToDelete is not false then

set cardToDelete to item 1 of cardToDelete

ASTID(" • ")

set newCardList to {}

repeat with theCard in allCards

if (text item 1 of cardToDelete ≠ item1 of theCard) ¬

or (text item 2 of cardToDelete ≠ item2 of theCard) ¬

or (text item 3 of cardToDelete ≠ item3 of theCard) ¬

or (text item 4 of cardToDelete ≠ item4 of theCard) ¬

then

copy theCard to the end of newCardList

end if

end repeat

ASTID("")

set allCards to newCardList

end if

else -- chercher une carte

set stringToSearch to checkEmptyDialog("Search " & SortBy & " :", "")

repeat with theCard in allCards

set (item5 of theCard) to SortBy

if stringToSearch is in (getInfos2() of theCard) then

copy (getInfos() of theCard) to the end of listeInfos

end if

end repeat

if listeInfos is {} then

display dialog myQuote & stringToSearch & myQuote & "is not found." buttons {"•"} default button 1 with icon 0

else

choose from list listeInfos with prompt "Result :"

end if

end CardList

>>Ouvrir le script dans l'éditeur

DataBase (1/5)

2008-07-06T04:08:00.001-07:00

property allCards : {} -- liste des scripts objets

property myQuote : ASCII character (34)

on run

set dataFilePath to ((path to me) as string) & "Contents:Resources:data.txt" -- fichier data

if allCards is {} then

set theData to read_file(dataFilePath as alias)

if theData is in {false, "list"} then

set allCards to {} -- fichier data.txt vide

else

set allCards to theData -- chargement scripts objets

end if

repeat

set btn to button returned of (display dialog "DataBase" buttons {"Quit", "New card...", "All cards"} default button 3 with icon 1)

if btn = "Quit" then

write_file(allCards, dataFilePath as alias)

exit repeat

else

if btn = "New card..." then

newCard()

else if btn = "All cards" then

CardList()

end if

write_file(allCards, dataFilePath as alias)

end if

end repeat

end run

>>Ouvrir le script dans l'éditeur
Exemple de base de données qui gère une bibliothèque illustrant la methode objet. Le script doit être enregistré au format "Application Bundle" pour contenir un fichier texte "data.txt" stockant les données. Le fichier "data.txt" est accessible par ctrl-clic ou clic droit sur le script puis menu contextuel "Show Package Contents".

1/5) Le script principal on run/end run gère l'interface de saisie des fiches de la bases de données. La base de données est chargée au lancement du script dans la variable "theData". Chaque fiche est une instance du script objet contenu dans le handler "createCard". Les fiches sont stockées dans la variable "allCards" qui est une liste des instances du script objet. Les differents items de chaque fiche (auteur, titre, sujet, édition) sont stockés dans les propriétés (property) de chaque instance du script objet.

2/5) Le handler CardList gère l'affichage des fiches, l'effacement d'une fiche et la recherche d'une fiche dans la base de données.

3/5) Le handler newCard crée une nouvelle fiche.

4/5) Le handler createCard contient le script objet proprement dit. Les fiches sont des instances de ce script objet qui sert de modèle. Les differents items de chaque fiche (auteur, titre, sujet, édition) sont stockés dans les propriétés de l'instance du script objet. Les deux handlers "getInfos" et "getInfos2" servent respectivement à l'affichage des fiches et à la recherche d'une fiche.

5/5) Les handlers read_file, write_file, checkEmptyDialog, ItemNumber et ASTID gèrent "les affaires courantes" comme dans un script classique, à savoir : Lecture du contenu d'un fichier, écriture dans un fichier, test de saisie d'une boite de dialogue, numéro d'item dans une liste, fixation du délimitateur d'item dans un script.

Get UNIX path

2008-06-09T02:09:00.001-07:00

Enregistrer le workflow au format plug-in Finder. Ctrl-clic ou clic droit sur un fichier et choisir More > Automator > Get UNIX path. Le chemin d'accès est copié dans le presse-papiers.
>>Télécharger l'action "Get UNIX path of files"

MacFixIt download

2008-06-04T11:10:00.001-07:00

Enregistrer le workflow au format plug-in iCal permet de télécharger la page du jour de MacFixIt.

Chrono

2008-06-02T23:47:00.000-07:00

script chrono

property time1 : null

property time2 : null

property theCount : null

on start() -- start chrono

set theCount to 0

set time1 to (the current date)

end start

on break() -- stop chrono

set time2 to (the current date)

activate

if theCount is not null then

display dialog (theCount as string) & plural(" item", theCount) & " proceded in " & formatSeconds(round (time2 - time1)) & " ." buttons {"OK"} default button 1 with icon 1 giving up after 10

else

display dialog "Process completed in " & formatSeconds(round (time2 - time1)) & " ." buttons {"OK"} default button 1 with icon 1 giving up after 10

end if

end break

on countLoop() -- increase counter

set theCount to theCount + 1

end countLoop

on formatSeconds(theSeconds)

set {h, m, s} to {theSeconds div 3600, (theSeconds mod 3600) div 60, (theSeconds mod 3600) mod 60}

return h & ":" & twoDigit(m) & ":" & twoDigit(s) as string

end formatSeconds

on twoDigit(theNumber) -- add zero before one digit number

if theNumber < 10 then set theNumber to "0" & theNumber

return theNumber as string

end twoDigit

on plural(theString, num) -- add "s" after a string if num> 1

if num > 1 then set theString to theString & "s"

return theString

end plural

end script

>>Ouvrir le script dans l'éditeur

Quantifie le gain de temps d'un operation automatisée vs "à la main" au prix d'un léger ralentissement si appel à la routine countloop()

tell chrono to start() -- Initialisation chronomètre : A placer au debut du script utilisateur
tell chrono to countLoop() -- incrementation compteur : A placer (facultatif) dans le script utilisateur, par ex. dans une routine qui renomme des fichiers.
tell chrono to break() -- Arrêt du chronomètre : A placer à la fin du script utilisateur.

Clean screenshots

2008-06-02T15:31:00.001-07:00

Clean Desktop

2008-06-02T15:14:00.000-07:00

En ajoutant ces deux actions autant de fois que nécessaire en les adaptant aux dossiers "movies", "documents","Pictures" et "Sites" on obtient un workflow qui permet de ranger les fichiers du bureau selon leur type dans les dossiers correspondants de Mac OS X.

Multiple find replace

2008-06-02T11:01:00.001-07:00

on nFindReplace(theText, string1, string2) -- multiple search replace

repeat with i from 1 to the length of my string1

set AppleScript's text item delimiters to character i of string1

set theList to text items of theText

set AppleScript's text item delimiters to character i of string2

set theText to theList as text

end repeat

set AppleScript's text item delimiters to ""

return theText

end nFindReplace

>>Ouvrir le script dans l'éditeur

Find replace

2008-06-02T11:00:00.001-07:00

on findReplace(theString, oldChar, newChar) -- search replace

set AppleScript's text item delimiters to oldChar

set theList to text items of theString

set AppleScript's text item delimiters to newChar

set theString to theList as text

set AppleScript's text item delimiters to ""

return theString

end findReplace

>>Ouvrir le script dans l'éditeur

Space to underscore (8/8)

2008-06-02T10:57:00.001-07:00

script space2underscore -- Remplacer espace par underscore

property parent : deleteSpace

property string1 : " "

property string2 : "_"

end script

>>Ouvrir le script dans l'éditeur

Delete space (7/8)

2008-06-02T10:55:00.000-07:00

script deleteSpace -- Supprimer espace

property string1 : " "

property string2 : ""

on myProcess(theText)

set theText to theText as text

findReplace(theText, my string1, my string2)

end myProcess

end script

>>Ouvrir le script dans l'éditeur

Ligature (6/8)

2008-06-02T10:54:00.001-07:00

script Ligature -- replacer les entrelacés

property entrelaces : {{"æ", "ae"}, {"Æ", "AE"}, {"œ", "oe"}, {"Œ", "OE"}}

on myProcess(theText)

set theText to theText as text

repeat with i in entrelaces

set theText to findReplace(theText, item 1 of i, item 2 of i)

end repeat

end myProcess

end script

>>Ouvrir le script dans l'éditeur

Diacritical (5/8)

2008-06-02T10:53:00.001-07:00

script diacritical -- Remplacer diacritiques

property parent : myupperCase

property string1 : "äëïöüâêîôûàèùéçñÄËÏÖÜÂÊÎÔÛÀÈÙÉÇÑ"

property string2 : "aeiouaeiouaeuecnAEIOUAEIOUAEUECN"

end script

>>Ouvrir le script dans l'éditeur

Upper case (4/8)

2008-06-02T10:51:00.001-07:00

script myupperCase -- Mettre en majuscules

property string1 : "æœäåçéñöüàãõÿâêáëèíîïìóôòúûùabcdefghijklmnopqrstuvwxyz"

property string2 : "ÆŒÄÅÇÉÑÖÜÀÃÕŸÂÊÁËÈÍÎÏÌÓÔÒÚÛÙABCDEFGHIJKLMNOPQRSTUVWXYZ"

on myProcess(theText)

set theText to theText as text

nFindReplace(theText, my string1, my string2)

end myProcess

end script

>>Ouvrir le script dans l'éditeur

Upper case words first letter (3/8)

2008-06-02T10:48:00.000-07:00

script upperCaseWordsFirstLetter -- Majuscules 1ère lettre des mots

property parent : myLowerCase

property string1 : "æœäåçéñöüàãõÿâêáëèíîïìóôòúûùabcdefghijklmnopqrstuvwxyz"

property string2 : "ÆŒÄÅÇÉÑÖÜÀÃÕŸÂÊÁËÈÍÎÏÌÓÔÒÚÛÙABCDEFGHIJKLMNOPQRSTUVWXYZ"

on myProcess(theText)

set theText to theText as text

set theText to continue myProcess(theText) -- script mylowerCase

set temp to ""

set AppleScript's text item delimiters to " "

--••• every word of "to-to pi,po" --> {"to", "to", "pi", "po"}

-- every text item of "to-to pi,po" --> {"to-to", "pi,po"}

set theWords to every text item of theText

set AppleScript's text item delimiters to ""

repeat with theWord in theWords

set firstChar to nFindReplace(first character of theWord, string1, string2)

if the length of theWord > 1 then

set temp to temp & firstChar & characters 2 thru -1 of theWord & " "

else -- mot d'une lettre

set temp to temp & firstChar & " "

end if

end repeat

return characters 1 thru -2 of temp as string -- effacement espace final

end myProcess

end script

>>Ouvrir le script dans l'éditeur

Upper case first letter (2/8)

2008-06-02T10:47:00.001-07:00

script upperCaseFirstLetter -- Majuscules 1ère lettre

property parent : myLowerCase

property string1 : "æœäåçéñöüàãõÿâêáëèíîïìóôòúûùabcdefghijklmnopqrstuvwxyz"

property string2 : "ÆŒÄÅÇÉÑÖÜÀÃÕŸÂÊÁËÈÍÎÏÌÓÔÒÚÛÙABCDEFGHIJKLMNOPQRSTUVWXYZ"

on myProcess(theText)

set theText to theText as text

set theText to continue myProcess(theText) -- script lowerCase

set firstChar to nFindReplace(first character of theText, string1, string2)

if the length of theText > 1 then

set theText to firstChar & characters 2 thru -1 of theText

else -- mot d'une lettre

set theText to firstChar

end if

return theText

end myProcess

end script

>>Ouvrir le script dans l'éditeur

Lower case (1/8)

2008-06-02T10:37:00.000-07:00

script myLowerCase -- Mettre en minuscules

property string1 : "ÆŒÄÅÇÉÑÖÜÀÃÕŸÂÊÁËÈÍÎÏÌÓÔÒÚÛÙABCDEFGHIJKLMNOPQRSTUVWXYZ"

property string2 : "æœäåçéñöüàãõÿâêáëèíîïìóôòúûùabcdefghijklmnopqrstuvwxyz"

on myProcess(theText)

set theText to theText as text

nFindReplace(theText, string1, string2)

end myProcess

end script

>>Ouvrir le script dans l'éditeur

Cette série de 8 scripts objets modifiant les caractères d'un texte (majuscule, minuscule, diacritique,etc.) illustre la notion d'héritage exposée dans >>Histoire d'héritage.

Round a number

2008-06-02T10:29:00.000-07:00

-- Parameters : number as string, number of decimals as integer

-- result : real

on Smart_Round(theNumber, theDecimal)

return (round (theNumber * (10 ^ theDecimal))) / (10 ^ theDecimal)

end Smart_Round

Auteur : Daniel Varlet

>>Ouvrir le script dans l'éditeur